Sütunda yazanları satıra aktarmak

[Thecoco]

Saygılar

Forumu sürekli kullanıyorum ve siz olmasanız ne yapardım bilmiyorum

Ekte gönderdiğim dosya ile ilgili yardımlarınızı rica ediyorum. Çok araştırdım ama yardımcı olabilecek bir yer bulamadım.

Şimdiden teşekkürler

 

[Huseyinkis]

Ekteki kodları deneyiniz.

sizin dosyada datalar "I" sutunundan başladığı için

For i = 1 To Cells(Rows.Count, 9).End(3).Row formulunde 9 kullandım
For a = 10 To Cells(i, Columns.Count).End(1).Column formulude I sutunundan 1 fazlası 10 ile başlıyor..

Cells(Sonsat, 1).Value = Cells(i, 9).Value burdaki dokuz gene I sutununu temsil ediyor.

sizn orjinaldosyanızda başlangıç I sutununda değil ise kodda ayarlama yapabilirsiniz.

Sub hk_Deneme()
For i = 1 To Cells(Rows.Count, 9).End(3).Row
For a = 10 To Cells(i, Columns.Count).End(1).Column
Sonsat = Cells(Rows.Count, 1).End(3).Row + 1
Cells(Sonsat, 1).Value = Cells(i, 9).Value
Sonsat2 = Cells(Rows.Count, 2).End(3).Row + 1
Cells(Sonsat2, 2).Value = Cells(i, a).Value
Next a
Next i
End Sub

 

[Ömer]

Merhaba,

Ben aktarımı tam tersi olarak algıladım. Alternatif olsun.

Sub OzetCikar()
 
    Dim s, a1, a2, deg, dizi, i As Long, j As Long
 
    Application.ScreenUpdating = False
    Range(Cells(9, "I"), Cells(Rows.Count, Columns.Count)).ClearContents
 
    With CreateObject("Scripting.Dictionary")
        For i = 1 To Cells(Rows.Count, "A").End(xlUp).Row
            deg = Cells(i, "A")
            If Not .exists(deg) Then
                s = Cells(i, "B")
                .Add deg, s
            Else
                s = .Item(deg)
                s = s & "-" & Cells(i, "B")
                .Item(deg) = s
            End If
        Next i
 
        a1 = .keys: a2 = .items
        For i = 0 To .Count - 1
            Cells(i + 1, "I") = a1(i)
            s = a2(i)
            dizi = Split(s, "-")
            For j = 0 To UBound(dizi)
                Cells(i + 1, j + 10) = dizi(j)
            Next j
        Next i
    End With
 
End Sub

.

 

[Huseyinkis]

Merhaba,

Ben aktarımı tam tersi olarak algıladım. Alternatif olsun.

.

Ben Ters algılamışım yazıyı tam okumadan işlmi yapmıştım

 

[Thecoco]

Ömer Bey harikasınız çok teşekkür ederim. Müthiş bir şekilde çalıştı ellerinize sağlık.

Hüseyin Bey sizde çok sağolun. Anlatımım biraz eksik gibi oldu kusura bakmayın.

Elleriniz dert görmesin