Hücredeki Değerleri Toplama

[volkan5454]

Merhaba arkadaşlar A 1-2-3-4 hücrelerinde aşağıda gördüğünüz gibi değerler yazıyor, değerler değişken ben bunları kendi aralarında toplamak istiyorum, ama bir türlü yapamadım bir yolu varmıdır bu işlemin. Şimdiden teşekkür ederim.

87 - 69
64 - 68
81 - 84
81 - 74

 

[Korhan Ayhan]

TOPLAMAK derken örnek verir misiniz?

 

[volkan5454]

TOPLAMAK derken örnek verir misiniz?

Örnek olarak A1 hücresinde 87 - 69 yazıyor hücrede yazan sayıları kendi aralarında toplama işlemi yapmak istiyorum çıkan sonuç 156 yı farklı bir hücreye yazmak istiyorum.

 

[EmrExcel16]

Deneyiniz.

=EĞERHATA(SAYIYAÇEVİR(SOLDAN($A2;BUL("-";$A2)-1))+SAYIYAÇEVİR(PARÇAAL($A2;BUL("-";$A2)+1;UZUNLUK($A2)));"")

 

[excel41]

alternatif olsun

TOPLA(SOLDAN(A1;BUL("-";A1)-2);SAĞDAN(A1;BUL("-";A1)-2))*1

 

[volkan5454]

Teşekkür ederim bigisayara geçince deneyeceğim

 

[Korhan Ayhan]

Hücrede birden fazla (-) tire sembolü ile ayrılan sayı varsa alternatif olarak aşağıdaki formülü deneyebilirsiniz.

=TOPLA.ÇARPIM(--YERİNEKOY(KIRP(0&PARÇAAL(YERİNEKOY(A1;"-";YİNELE(" ";UZUNLUK(A1)));1+((SATIR(DOLAYLI("$1:"&(1+UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;"-";"")))))-1)*UZUNLUK(A1));UZUNLUK(A1)));" ";""))

 

[Merhum İdris SERDAR]

.

Arkadaşlarımız sağ olsun. bu soruya formüllerle yanıtlar vermişler.

Soruyu soran arkadaşım, Excel'in Text to Column - Metin Sütunlara her neyse özelliğini biliyor musun? Biliyorsan;

Bunu yaptıktan sonra ister bunları topla, çıkar, çarp böl ne istersen yap.

Ha, bilmiyorum dersen. O zaman bu verilen formülleri anlamak için çok çalışman gerekecek. Benden söylemesi...

Ayrıca KTF (Kullanıcı Tanımlı Fonksiyon) ile şöyle yapılabilir.

Bir modüleye aşağıdaki kodları yazın.

Function HESAPLA(mtn As String)
    Application.Volatile
    HESAPLA = Evaluate(Evaluate(Replace(mtn, "-", "+")))
End Function

=HESAPLA(A)

yazıp, aşağıya doğru koyalayın.

.





.

 

[i3uz]

Selamlar, çok baktım ama hiç biyerde bulamadım. bir hücredeki sayıları kendi arasında toplamak,
örnek:
hücrede 4256 yazıyor, rakam toplamı 17 gibi, sonuç başka hücrede 17 yazacak.
hücrede 40 yazıyor, rakam toplamı 4 gibi, sonuç başka hücrede 4 yazacak.
hücrede 4 yazıyor, rakam toplamı 4 gibi, sonuç başka hücrede 4 yazacak.

sonuç olarak hücredeki sayının basamaklar arasında toplamını öğrenmek istiyorum. şimdiden teşekkürler

 

[Merhum İdris SERDAR]

Aşağıdaki formüllerden birini kullanabilirsiniz.

Sayı A1 hücresinde ise:

Dizi formülüdür.
=SUM(IFERROR(1*MID(A1;ROW($1:$99);1);))

=SUMPRODUCT(IFERROR(1*MID(A1;ROW($1:$99);1);))

=SUMPRODUCT(1*MID(A1;ROW(INDIRECT("1:"&LEN(A1)));1))

.

 

[i3uz]

Aşağıdaki formüllerden birini kullanabilirsiniz.

Sayı A1 hücresinde ise:

Dizi formülüdür.
=SUM(IFERROR(1*MID(A1;ROW($1:$99);1);))

=SUMPRODUCT(IFERROR(1*MID(A1;ROW($1:$99);1);))

=SUMPRODUCT(1*MID(A1;ROW(INDIRECT("1:"&LEN(A1)));1))

.

selamlar, teşekkürler cevabınız için ama formulu koydugumda A1 hücresine 45 yazıyorum sonuç hücresinde #AD olarak gözüyor.

 

[Merhum İdris SERDAR]

Profilinizde Excel'in dili ve sürümünü yazmadığınız için ben de işlevleri kullandığım sürümün diline göre İngilizce verdim.

Türkçeleri:

=TOPLA(EĞERHATA(1*PARÇAAL(A1;SATIR($1:$99);1);))

=TOPLA.ÇARPIM(EĞERHATA(1*PARÇAAL(A1;SATIR($1:$99);1);))

=TOPLA.ÇARPIM(1*PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1))

.

 

[i3uz]

Profilinizde Excel'in dili ve sürümünü yazmadığınız için ben de işlevleri kullandığım sürümün diline göre İngilizce verdim.

Türkçeleri:

=TOPLA(EĞERHATA(1*PARÇAAL(A1;SATIR($1:$99);1);))

=TOPLA.ÇARPIM(EĞERHATA(1*PARÇAAL(A1;SATIR($1:$99);1);))

=TOPLA.ÇARPIM(1*PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1))

.

selamlar teşekkürler. 3cü kod işime gördü. güzel çalışıyor.