Hücre içinden bir kısım değer alma

[violent2]

Değerli arkadaşlar kolay gelsin.. Bir hücrede - işareti ile ayrılmış yazı ve sayılar var iç anadolu bölge-ankara(503)-710/90000-cevap dönmedi-muhabere40 gibi.. benim isteğim iki - işareti arasındaki veriyi başka bir hücreye almak..

örneğin -710/9000- bu aradaki veriyi almak istiyorum.. bul formülü ile ilk - işaretini bulabildigim için tam hedefime ulasamadım.. acaba nasıl bir yol izlemem gerek? teşekkür ederim..

 

[carlosfatih]

Merhaba,

Bölmek istediğiniz metni içeren hücreyi veya sütunu seçin.

NOT İstediğiniz kadar satır, ancak sadece tek bir sütun seçin. Herhangi bir öğenin üzerine yazılmaması için sağda yeterince boş sütun olduğundan emin olun. Yeterli boş sütun yoksa, bunları ekleyin.

Veri >Metni Sütunlara Dönüştür öğesini tıklatın.

Bu, Metni Sütunlara Dönüştürme Sihirbazı'nı başlatır. Sınırlandırılmış > İleri'ye tıklayın.

Boşluk'u işaretleyin, geri kalan kutuların işaretlerini kaldırın veya metninizin nasıl bölüneceğine bağlı olarak Virgül ve Boşluk'u işaretleyin (Göktepe, Mete, adlar arasına virgülle ve boşluk konur). Veri önizleme penceresinde verilerinizi önizleyebilirsiniz.
İleri’ye tıklayın.

Bu adımda, yeni sütunlarınızın biçimini seçersiniz veya bunu sizin yerinize Excel'in yapmasını sağlayabilirsiniz. Kendi biçiminizi seçmek isterseniz, seçin (örneğin Metin), Veri önizleme penceresinde ikinci veri sütununu tıklatın, ardından aynı biçimi tekrar tıklatın. Bunu önizlemepenceresinde tüm sütunlar için tekrarlayın.
Hedef kutusunun sağındaki İletişim Kutusunu Daralt düğmesi resmi düğmesine tıklayıp iletişim kutusunu daraltın.

Çalışma kitabınızda bölünmüş verileri yapıştırmak istediğiniz hücreleri seçin. Örneğin, tam adı ad ve soyadı sütunu olarak bölüyorsanız, bitişik iki sütunda uygun hücre sayısını seçin.
İletişim Kutusunu Genişlet resmi düğmesine tıklayıp iletişim kutusunu genişletin, sonra Son'a tıklayın.

Kaynak: microsoft

 

[Ömer BARAN]

Merhaba. Foruma hoşgeldiniz.

Formül ile çözüm bulmak isterseniz, aşağıdaki şekilde olabilir.

Verinin A1 hücresinde olduğu varsayılmıştır.
1) Metin içerisindeki ) işareti standart ve ) işaretinden sonraki iki - arasını almak istiyorsanız.

=PARÇAAL(A1;BUL(")";A1;1)+2;BUL("-";A1;BUL(")";A1;1)+2)-BUL(")";A1;1)-2)

2) Metin içerisisinde ) işareti standart değil, 2'nici ile 3'üncü - işaretinin arasını arasını almak istiyorsanız.

=PARÇAAL(A1;BUL("-";A1;BUL("-";A1;1)+1)+1;BUL("-";A1;BUL("-";A1;BUL("-";A1;1)+1)+1)-BUL("-";A1;BUL("-";A1;1)+1)-1)

 

[violent2]

Üstadlarım öncelikle ilginize ve alakanıza çok teşekkür ederim.. Ömer beyin formülü tam anlamıyla ihtiyacımı karşıladı.. Tekrar teşekkür ediyorum..

 

[katip06]

Merhaba. Foruma hoşgeldiniz.

Formül ile çözüm bulmak isterseniz, aşağıdaki şekilde olabilir.

Verinin A1 hücresinde olduğu varsayılmıştır.
1) Metin içerisindeki ) işareti standart ve ) işaretinden sonraki iki - arasını almak istiyorsanız.

=PARÇAAL(A1;BUL(")";A1;1)+2;BUL("-";A1;BUL(")";A1;1)+2)-BUL(")";A1;1)-2)

2) Metin içerisisinde ) işareti standart değil, 2'nici ile 3'üncü - işaretinin arasını arasını almak istiyorsanız.

=PARÇAAL(A1;BUL("-";A1;BUL("-";A1;1)+1)+1;BUL("-";A1;BUL("-";A1;BUL("-";A1;1)+1)+1)-BUL("-";A1;BUL("-";A1;1)+1)-1)

Ömer hocam sadece paranteze kadar olan kısmı almak istesek formül nasıl olur. Mesela; Ali Veli (1111), Ali Veli olarak alması için.

 

[Korhan Ayhan]

Böyle verileri parçalarken adım adım gitmek en pratik çözümdür.

Öncelikle metinde ki aranacak karakteri belirliyoruz ki en önemli nokta burasıdır. Siz "aç parantez" karakterine göre ayırma talep etmişsiniz.

Bu karakterin metin içindeki sırasını bulmak için BUL fonskiyonunu kullanabiliriz.

=BUL("(";A1;1)

Burada şunu dedik. A1 hücresinde "aç parantez" karakterini 1 karakterden itibaren ara ve sıra numarasını ver.

Bundan sonrası işin kolay kısmı.

Şimdi metinden istediğimiz parçayı alalım. Bunun için de PARÇAAL fonksiyonunu kullanabiliriz.

=PARÇAAL(A1;1;?)

Burada ise şunu ifade ettik. A1 hücresindeki metinin 1. karakterinden ? (soru işareti) kadar karakter al.

Burada ? (soru işareti yerine ilk formülümüzü yerleştireceğiz ve fonksiyon son halini alacak.

=PARÇAAL(A1;1;BUL("(";A1;1))

Bu fonksiyon bize "Ali Veli (" ifadesini döndürecektir. Sondaki parantezden kurtulmak için fonksiyonu aşağıdaki şekilde düzenlemek yeterli olacaktır.

=PARÇAAL(A1;1;BUL("(";A1;1)-1)

Bu fonksiyon bize "Ali Veli " ifadesini döndürecektir. Sondaki boşluktan kurtulmak için fonksiyonu aşağıdaki şekilde düzenlemek yeterli olacaktır.

=KIRP(PARÇAAL(A1;1;BUL("(";A1;1)-1))

 

[katip06]

Böyle verileri parçalarken adım adım gitmek en pratik çözümdür.

Öncelikle metinde ki aranacak karakteri belirliyoruz ki en önemli nokta burasıdır. Siz "aç parantez" karakterine göre ayırma talep etmişsiniz.

Bu karakterin metin içindeki sırasını bulmak için BUL fonskiyonunu kullanabiliriz.

=BUL("(";A1;1)

Burada şunu dedik. A1 hücresinde "aç parantez" karakterini 1 karakterden itibaren ara ve sıra numarasını ver.

Bundan sonrası işin kolay kısmı.

Şimdi metinden istediğimiz parçayı alalım. Bunun için de PARÇAAL fonksiyonunu kullanabiliriz.

=PARÇAAL(A1;1;?)

Burada ise şunu ifade ettik. A1 hücresindeki metinin 1. karakterinden ? (soru işareti) kadar karakter al.

Burada ? (soru işareti yerine ilk formülümüzü yerleştireceğiz ve fonksiyon son halini alacak.

=PARÇAAL(A1;1;BUL("(";A1;1))

Bu fonksiyon bize "Ali Veli (" ifadesini döndürecektir. Sondaki parantezden kurtulmak için fonksiyonu aşağıdaki şekilde düzenlemek yeterli olacaktır.

=PARÇAAL(A1;1;BUL("(";A1;1)-1)

Bu fonksiyon bize "Ali Veli " ifadesini döndürecektir. Sondaki boşluktan kurtulmak için fonksiyonu aşağıdaki şekilde düzenlemek yeterli olacaktır.

=KIRP(PARÇAAL(A1;1;BUL("(";A1;1)-1))

Korhan Ayhan Hocam çok sağol eline emeğine sağlık