Hücre içindeki satırlara tek birleşim

[lewofly]

Tek hücre içindeki birçok satırın sonuna başka bir hücreyi birleştirmek istiyorum. Ekteki dosyada yapmak istediğimn bir örneği var. Bu konuda bana yardımcı olursanız sevinirim..teşekkür ederim..

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu denermisiniz.

Option Explicit
 
Sub VERİLERİ_DÜZENLE()
    Dim X As Long, AYIR() As String, Y As Byte, VERİ As String
    
    Application.ScreenUpdating = False
    
    Sheets("SONUÇ").Range("A2:B65536").ClearContents
    
    For X = 2 To Sheets("SORU").Range("A65536").End(3).Row
        If Sheets("SORU").Cells(X, 1) <> "" Then
            AYIR = Split(Sheets("SORU").Cells(X, 1), Chr(10))
            For Y = 0 To UBound(AYIR)
                If VERİ = "" Then
                    VERİ = AYIR(Y) & "-" & Sheets("SORU").Cells(X, 2)
                Else
                    VERİ = VERİ & Chr(10) & AYIR(Y) & "-" & Sheets("SORU").Cells(X, 2)
                End If
            Next
            
            Sheets("SONUÇ").Cells(X, 1) = VERİ
            Sheets("SONUÇ").Cells(X, 2) = Sheets("SORU").Cells(X, 2)
            VERİ = ""
        End If
    Next
    
    Sheets("SONUÇ").Select
    Application.ScreenUpdating = True
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[janveljan]

Bu da bir alternatif olabilir, alt+enter ları sağdaki hücre ile değiştirip en sonada sağdaki hücreyi eklemek.

Sub Makro1()
    For i = 1 To [A1].End(xlDown).Row
        Cells(i, 1).Replace What:=Chr(10), Replacement:="-" & Cells(i, 2) & Chr(10)
        Cells(i, 1) = Cells(i, 1) & "-" & Cells(i, 2)
    Next
End Sub

 

[lewofly]

Arkadaşlar çok teşekkür ederim allah razı olsun...bu arada hayırlı bayramlar...
Bir sorum daha olacak ben bu işi sizin gibi öğrenmek istiyorum nasıl öğrenebilirim yol gösterebilir misiniz_?

 

[Korhan Ayhan]

Selamlar,

Makroları öğrenmek için işin en başından başlamalısınız. Forumdaki kitap satış bölümünden kitaplar alıp başlangıç yapabilirsiniz. Bu tarz kitapları nette arayarakta bulabilirsiniz. Bunlara ek olarak forumumuzun dersane bölümündeki konuları sindirerek incelerseniz size çok faydalı olacaktır. Biraz bilgi birikimi olduğunda ise sürekli denemeler yaparak kendinizi daha hızlı bir şekilde geliştirebilirsiniz.

Kolay gelsin.