Excel sayfalarını başka klasöre kopyalamak

[zırzır]

Arkadaşlar.hafta.xls adlı excel kitabındaki "yıl ve as" adlı iki sayfayı "D" sürücüsündeki "arşiv" adlı klasöre o günün tarihi ile bire bir kopyalayabilirmiyim.Üçüncü sayfa olan "gun" sayfası kesinlikle
kopyalanmayacak .Yardımlarınızı bekliyorum.

 

[N.Ziya Hiçdurmaz]

Yanıt

Sub Yedek_Al()
    On Error Resume Next
    Dim FSO As Object
    Dim MyFolder, MyFile, MyFileEnd As String
    Dim S As Long
    MyFolder = "D:\ARŞİV"
    MyFile = "YEDEK DOSYA ADINIZ"
    MyFileEnd = MyFile & " " & Format(Now, "dd mm yyyy") & ".xls"
    Set FSO = CreateObject("Scripting.FileSystemObject")
    
    If Not FSO.FolderExists(MyFolder) Then
    FSO.CreateFolder (MyFolder)
    End If
    
    ActiveWorkbook.SaveCopyAs Filename:=MyFolder & Application.PathSeparator & MyFileEnd
    
    Set FSO = Nothing
    Workbooks.Open "D:\ARŞİV\" & MyFileEnd
    Application.DisplayAlerts = False
    Sheets("gun").Delete
    Application.DisplayAlerts = True
    ActiveWorkbook.Save
    ActiveWorkbook.Close
End Sub

 

[veyselemre]

Alternatif,

Sub SayfalariYeniKitaplaraAktar()
    Application.ScreenUpdating = False

    Set wb = ActiveWorkbook

    MyFolder = "D:\ARŞİV"
    MyFile = "YEDEK DOSYA ADINIZ" & " " & Format(Now, "dd mm yyyy") & ".xls"

    Set FSO = CreateObject("Scripting.FileSystemObject")
    If Not FSO.FolderExists(MyFolder) Then
        FSO.CreateFolder (MyFolder)
    End If

    Sheets(Array("as", "yıl")).Copy
    Set wb1 = ActiveWorkbook
    wb1.SaveAs Filename:=MyFolder & "\" & MyFile
    wb1.Close
    wb.Activate

Set wb = Nothing
Set FSO = Nothing
Application.ScreenUpdating = True
End Sub

 

[zırzır]

Arkadaşlar,gösterdiğiniz ilgiye teşekkür ederim.Ellerinize sağlık.Sayenizde işlerim kolaylaştı.

 

[tamer42]

Merhbalar,

bu konuda; Aynı dosyanın daha önce oluşturulmuş kopyaların klasör içerisinden silinmesi, klasörde devamlı olarak bir kopyanın (en güncel) olması

2. olarakta;

ActiveWorkbook.SaveCopyAs ............

İşlemi sonunda aktif olan dosya ilk dosya mıdır? Yoksa kopya edilen dosya mıdır?


İyi Çalışmalar.

 

[zırzır]

Sayın Tamer42,işlem sonunda aktif olan ilk dosyadır.Burada aktif olan dosyadan,kopyalanan dosyada istenilen sayfaların oluşturulması.
Saygılar

 

[woyzeck]

Merhaba Arkadaşlar,
Ellerinize sağlık çok güzel bir çalışma olmuş.

ek olarak sormak istediğim buraya kopyalanmasını istediğimiz sayfanın belli aralıktaki hücrelerini kopyalama sağlanabilir mi?

ben şunu denedim ama dosya malesef kendi kendine kapanıyor. yani işe yaramıyor.

Sheets(Array("as", "yıl")).range("a12:c190").Copy

Bunu Sorma nedenim, "Sheets(Array("as", "yıl")).Copy" komutu dosyadaki bütün userformların da yedeğini almasıdır. böylece yedek dosya boyutları çok yüksek olmakta.

Şimdiden teşekkürler.

 

[hussain]

tesekkurler