Çözüldü Formül içindeki tarih olarak girilen sayfa adını otomatik güncelleme

Katılım
31 Ağustos 2014
Mesajlar
13
Excel Vers. ve Dili
2019
Arkadaşlar öncelikle merhaba.

Bir çalışmam var. Bu çalışmamda sayfa adlarım tarihlerden oluşuyor. Günlük çalışma raporu...

Sayfa adlarım 17.11.2018, 18.11.2018 şeklinde günlük olarak devam ediyor. Ancak formüllerimdeki "sayfa adı" değişkenlerinin otomatik güncelleştirilmesini sağlayamadım. Bunun başlıca sebebi sayfa adlarını tırnak içinde belirtmem diye düşünüyorum.

=EĞER(YADA('16.11.2018'!J9<0;'16.11.2018'!J9=0);"";'16.11.2018'!J9)

Formül bugünkü 17.11.2018 adlı sayfamda mevcut haliyle bu. Yarın yeni sayfa adım 18.11.2018 olacağı için formüldeki 16.11.2018 değişkenlerinin otomatik olarak 17.11.2018 tarihine güncellenmesini istiyorum. Çok uğraştım ama olmadı.

Bu konuda yardımcı olabilirseniz memnun olurum.
 
Katılım
6 Mart 2005
Mesajlar
6,238
Excel Vers. ve Dili
Excel Vers. ve Dili:
Office 2016 TR 64 Bit
Bu şekilde deneyiniz.
Kod:
=EĞER(YADA(DOLAYLI(METNEÇEVİR(BUGÜN();"gg.aa.yyyy")&"!J9")<9;DOLAYLI(METNEÇEVİR(BUGÜN();"gg.aa.yyyy")&"!J9")=9);"";DOLAYLI(METNEÇEVİR(BUGÜN();"gg.aa.yyyy")&"!J9"))
 
Katılım
31 Ağustos 2014
Mesajlar
13
Excel Vers. ve Dili
2019
Öncelikle çok teşekkür ediyorum :) Metine çevirmem gerektiğini tahmin ediyordum tırnak arasında olduğu için ama metneçevir'den bihaberdim :)

Bir şey daha sormak istiyorum.

=EĞER(YADA(DOLAYLI(METNEÇEVİR(K5;"gg.aa.yyyy")&"!J9")<9;DOLAYLI(METNEÇEVİR(K5;"gg.aa.yyyy")&"!J9")=9);"";DOLAYLI(METNEÇEVİR(K5;"gg.aa.yyyy")&"!J9"))

BUGÜN() değişkeni yerine tarihi K5 hücresinden okuttum ama bu sefer bu formülü alt satırlara kopyaladığımda K6-K7-K8 şeklinde değişiyor. Halbuki tarih K5'te yazıyor sadece. Bunun kopyalarken değişmemesini sağlayabilir miyiz?

Veya daha pratik olan yoldan sorayım. BUGÜN() yerine sayfa adını okutup -1 yapabilir miyiz. Sayfa adı 17.11.2019 ise 16.11.2019 yazacak. Sizin bugün yazdığınız yerlerde.

teşekkürler :)
 

muygun

Özel Üye
Katılım
6 Temmuz 2004
Mesajlar
9,103
Excel Vers. ve Dili
Excel-2003 Türkçe
Merhaba;
Formül uygulayacağınız sayfa adının tarih formatında örn. 16.11.2018 gibi ve bu tarihin 1 fazlasından veri alacaksanız;
=EĞER(YADA(DOLAYLI(METNEÇEVİR(SAĞDAN(HÜCRE("dosyaadı";A1);UZUNLUK(HÜCRE("dosyaadı";A1))-(BUL("]";HÜCRE("dosyaadı";A1))))+1;"gg.aa.yyyy")&"!j9")<0;DOLAYLI(METNEÇEVİR(SAĞDAN(HÜCRE("dosyaadı";A1);UZUNLUK(HÜCRE("dosyaadı";A1))-(BUL("]";HÜCRE("dosyaadı";A1))))+1;"gg.aa.yyyy")&"!j9")=0);"";DOLAYLI(METNEÇEVİR(SAĞDAN(HÜCRE("dosyaadı";A1);UZUNLUK(HÜCRE("dosyaadı";A1))-(BUL("]";HÜCRE("dosyaadı";A1))))+1;"gg.aa.yyyy")&"!j9"))

Gibi formül uygulanabilir.

Bu formül çok karmaşık geldiyse;
A1 hücresine;
=METNEÇEVİR(SAĞDAN(HÜCRE("dosyaadı";A1);UZUNLUK(HÜCRE("dosyaadı";A1))-(BUL("]";HÜCRE("dosyaadı";A1))))+1;"gg.aa.yyyy")
formülünü uygularsanız ve bulunduğu sayfa adı tarih formatındaysa 1 fazla tarih elde edersiniz
artık bu adresi;
=EĞER(YADA(DOLAYLI(A1&"!J9")<0;DOLAYLI(A1&"!J9")=0);"";DOLAYLI(A1&"!J9"))
Şeklinde formülde kullanabilirsiniz.

İkinci yöntem daha mantıklı
İyi çalışmalar.

NOT: Syn çıtır'ın cevabını görmeden göndermiştim.
 
Son düzenleme:
Katılım
6 Mart 2005
Mesajlar
6,238
Excel Vers. ve Dili
Excel Vers. ve Dili:
Office 2016 TR 64 Bit
Öncelikle çok teşekkür ediyorum :) Metine çevirmem gerektiğini tahmin ediyordum tırnak arasında olduğu için ama metneçevir'den bihaberdim :)

Bir şey daha sormak istiyorum.

=EĞER(YADA(DOLAYLI(METNEÇEVİR(K5;"gg.aa.yyyy")&"!J9")<9;DOLAYLI(METNEÇEVİR(K5;"gg.aa.yyyy")&"!J9")=9);"";DOLAYLI(METNEÇEVİR(K5;"gg.aa.yyyy")&"!J9"))

BUGÜN() değişkeni yerine tarihi K5 hücresinden okuttum ama bu sefer bu formülü alt satırlara kopyaladığımda K6-K7-K8 şeklinde değişiyor. Halbuki tarih K5'te yazıyor sadece. Bunun kopyalarken değişmemesini sağlayabilir miyiz?

Veya daha pratik olan yoldan sorayım. BUGÜN() yerine sayfa adını okutup -1 yapabilir miyiz. Sayfa adı 17.11.2019 ise 16.11.2019 yazacak. Sizin bugün yazdığınız yerlerde.

teşekkürler :)
Rica ederim.Dönüş yaptığınız için teşekkür ederim.
Aşağıdaki şekilde deneyiniz.
Kod:
=EĞER(YADA(DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9")<9;DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9")=9);"";DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9"))
veya aşağıdaki şekilde de olur
Kod:
=EĞER(DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9")<=9;"";DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9"))
 
Son düzenleme:
Katılım
31 Ağustos 2014
Mesajlar
13
Excel Vers. ve Dili
2019
Dostlar ikinize de teşekkür ederim. Çok yardımcı oldunuz. Sayın muygun cevabı görmeden göndermişsiniz ama biraz kendimi geliştirmek anlamında baktığım için sizin cevabınız da çok işime yaradı. Artık her hücredeki formülde metneçevir kullanmama gerek kalmayacak. Sayın çıtır bir güzellik daha yaptı yada yerine <= kullanabileceğimi önerdi bu da formülü kısalttı :) Yoğunluktan akla gelmeyebiliyor pratik çözümler.

Burada tek aşamadığım bir şey kaldı. Ancak çok önemli değil. Elle de düzeltebilirim hepsini.

Sonuç formülünü alttaki çok sayıda satıra kopyalayacağımı düşünelim.

Bir formülde her iki değişken güncelleniyor, diğerinde ikisi de sabit kalıyor.
=EĞER(DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9")<=0;"";DOLAYLI(METNEÇEVİR($K$5-1;"gg.aa.yyyy")&"!J9"))
=EĞER(YADA(DOLAYLI(K5&"!J9")<0;DOLAYLI(K5&"!J9")=0);"";DOLAYLI(K5&"!J9"))

Şu şekilde kullanmaya karar verdim.
=EĞER(DOLAYLI(K5&"!J19")<=0;"";DOLAYLI(K5&"!J19"))

Ancak bunu alttaki satırlara kopyaladığımda, K5'in sabit J19'un da 20,21,22 şeklinde değişmesini nasıl sağlarım. Aksi takdirde alt satırlara elle J20 J21 şeklinde düzeltme uygulamam gerekecek.

Bu konuyla ilgili son sorumdu. Çok yordum sizi :)
 
Katılım
6 Mart 2005
Mesajlar
6,238
Excel Vers. ve Dili
Excel Vers. ve Dili:
Office 2016 TR 64 Bit
Sayın noneik;
Konuya girişinizde sorunuzu aşağıdaki şekilde özetlemişsiniz.
Arkadaşlar öncelikle merhaba.
Bir çalışmam var. Bu çalışmamda sayfa adlarım tarihlerden oluşuyor. Günlük çalışma raporu...
Sayfa adlarım 17.11.2018, 18.11.2018 şeklinde günlük olarak devam ediyor. Ancak formüllerimdeki "sayfa adı" değişkenlerinin otomatik güncelleştirilmesini sağlayamadım. Bunun başlıca sebebi sayfa adlarını tırnak içinde belirtmem diye düşünüyorum.

Bir başka cevabınızda
BUGÜN() değişkeni yerine tarihi K5 hücresinden okuttum.
Buna göre
K5 sabitlendi.Sayfa adları tarih ise metne çevir kullanmanız gerekir aksi taldirde sayıya dönüşür ve ilgili sayfayı bulamaz önerim.Aşağıdaki şekilde kullanmanızdır.
Kod:
=EĞER(DOLAYLI(METNEÇEVİR($K$5;"gg.aa.yyyy")&"!J"&SATIR(A19))<=0;"";DOLAYLI(METNEÇEVİR($K$5;"gg.aa.yyyy")&"!J"&SATIR(A19)))
 
Son düzenleme:
Katılım
31 Ağustos 2014
Mesajlar
13
Excel Vers. ve Dili
2019
Sayın çıtır. Tekrar çok teşekkürler. Son mesajınızda haklısınız. Ben yapmak istediklerimi açıkça size aktaramamışım. İlk sorunumu çözmüştünüz. İkinci sorum da elde ettiğim formülü alt alta örneğin yüz adet satıra kopyalarken K5 yani tarih aldığım değişkenin sabit kalmaması ve J19 J20 vb. değişkenin yeni satırın değerine göre güncellenmemesiydi. Ama siz yine de son cevabınızla beni bu kısımda da aydınlatmış oldunuz.

Son haliyle; tarih okuttuğum K5'i $ sembolü ile sabitledim. Sabit kalmasını istemediğim J19'u da son gösterdiğiniz SATIR ile değişken haline getirdim. Şimdi formülüm çok güzel çalıştı. Hem alta kopyalarken, hem de yeni tarihe geçerken istediğim şekilde güncelleniyor.

Bu arada formül metneçevir olmadan da çalışıyor.

Son formülüm alt alta satırlarda şöyle çalışır hale geldi.

=EĞER(DOLAYLI($K$5&"!J"&SATIR(A11))<=0;"";DOLAYLI($K$5&"!J"&SATIR(A11)))
=EĞER(DOLAYLI($K$5&"!J"&SATIR(A12))<=0;"";DOLAYLI($K$5&"!J"&SATIR(A12)))
=EĞER(DOLAYLI($K$5&"!J"&SATIR(A13))<=0;"";DOLAYLI($K$5&"!J"&SATIR(A13)))

şeklinde kaç satır varsa devam ediyor. Ve yeni sayfaya geçtiğimde güncel tarihe göre verileri güncelliyor.

Sade bir şekilde anlatamıyorum galiba ondan biraz karıştırdım kafanızı.

İş hali kusura bakmayın.

Çok sağ olun.

İyi günler dilerim.
 
Katılım
31 Ağustos 2014
Mesajlar
13
Excel Vers. ve Dili
2019
Sayın çıtır

Dosyayı olduğu gibi paylaşamam. Çünkü şirketimin veri dosyası. Sadeleştirip paylaşabilirim ancak ağımızda "FortiGuard Web Filter" var.

"METNEÇEVİR" olmadan çalıştı dediğim için bunu talep ettiniz galiba.

Sayın muygun'un önerdiği yolla çözdüm onu. Tarih çağıracağım bir hücreye metneçevir uyguladım. Artık her hücrede metneçevir kullanma zorunluluğu olmadan ilgili tarihi çağırabiliyor. (O da bildiğiniz gibi K5 hücresi)
 
Katılım
6 Mart 2005
Mesajlar
6,238
Excel Vers. ve Dili
Excel Vers. ve Dili:
Office 2016 TR 64 Bit
Anladım.Bu durumda formülün bulunduğu sayfanın adı da tarih ve sabit olmalı.Hoşçakalın. :)
 
Son düzenleme:
Katılım
31 Ağustos 2014
Mesajlar
13
Excel Vers. ve Dili
2019
Doğrudur. İlk belirttiğim şey oydu zaten. Teşekkür ederim. Bir sonraki yardım talebime istinaden altın üyeniz olurum artık :)
 

ibere

Altın Üye
Katılım
31 Mart 2018
Mesajlar
127
Excel Vers. ve Dili
Office 365
Bu şekilde deneyiniz.
Kod:
=EĞER(YADA(DOLAYLI(METNEÇEVİR(BUGÜN();"gg.aa.yyyy")&"!J9")<9;DOLAYLI(METNEÇEVİR(BUGÜN();"gg.aa.yyyy")&"!J9")=9);"";DOLAYLI(METNEÇEVİR(BUGÜN();"gg.aa.yyyy")&"!J9"))
1.3.2020 2.3.2020 şeklinde devam eden günlük rapor dosyam var. BUGÜN() ü A1 yaptıgım zaman #BAŞV! hatası veriyor. Nerden hata kaynaklanıyor olabilir acaba ?
 

Mahir64

Destek Ekibi
Destek Ekibi
Katılım
19 Nisan 2006
Mesajlar
6,667
Excel Vers. ve Dili
Excel 2013-Türkçe
Excel 2016-Türkçe
Merhaba,
A1 hücresinde ne yazıyor?

Tarih yazıyorsa formatı uygun mu?
 

Mahir64

Destek Ekibi
Destek Ekibi
Katılım
19 Nisan 2006
Mesajlar
6,667
Excel Vers. ve Dili
Excel 2013-Türkçe
Excel 2016-Türkçe
Anladığım kadarıyla alıntı üzerinde değişiklik yapma düşüncesindesiniz.

Safa adınızı 01.03.2020 , 02.03.2020 ... 12.03.2020 bu şekilde yazmalısınız.
 

ibere

Altın Üye
Katılım
31 Mart 2018
Mesajlar
127
Excel Vers. ve Dili
Office 365
Anladığım kadarıyla alıntı üzerinde değişiklik yapma düşüncesindesiniz.

Safa adınızı 01.03.2020 , 02.03.2020 ... 12.03.2020 bu şekilde yazmalısınız.
Mahir bey dediğiniz üzere dosya ismini 01.03.2020 şeklinde düzeltince kod çalıştı. Sadece merakımdan soruyorum, bunu 1.03.2020 şeklinde çalıştıramaz mıyız ? Çok teşekkür ederim çok makbule geçti.
 

ibere

Altın Üye
Katılım
31 Mart 2018
Mesajlar
127
Excel Vers. ve Dili
Office 365
Mahir bey dediğiniz üzere dosya ismini 01.03.2020 şeklinde düzeltince kod çalıştı. Sadece merakımdan soruyorum, bunu 1.03.2020 şeklinde çalıştıramaz mıyız ? Çok teşekkür ederim çok makbule geçti.
Sorunu çözdüm, belki ilerde birinin ihtiyacı olur. Mahir bey size çok teşekkür ediyorum.

=EĞER(YADA(DOLAYLI(METNEÇEVİR(A1;"g.aa.yyyy")&"!J9")<9;DOLAYLI(METNEÇEVİR(A1;"g.aa.yyyy")&"!J9")=9);"";DOLAYLI(METNEÇEVİR(A1;"g.aa.yyyy")&"!J9"))
 

Mahir64

Destek Ekibi
Destek Ekibi
Katılım
19 Nisan 2006
Mesajlar
6,667
Excel Vers. ve Dili
Excel 2013-Türkçe
Excel 2016-Türkçe
Mahir bey dediğiniz üzere dosya ismini 01.03.2020 şeklinde düzeltince kod çalıştı. Sadece merakımdan soruyorum, bunu 1.03.2020 şeklinde çalıştıramaz mıyız ? Çok teşekkür ederim çok makbule geçti.
METNEÇEVİR(A1;"g.a.yyyy") yazarak deneyin
METNEÇEVİR formülünü kendinize göre revize edin.

Formülü şu şekilde de kısaltabiliriz.
Kod:
=EĞER(DOLAYLI(METNEÇEVİR(A1;"g.a.yyyy")&"!J9")<=9;"";DOLAYLI(METNEÇEVİR(A1;"g.a.yyyy")&"!J9"))
 
Üst