Excel Forum

Excel Forum (http://www.excel.web.tr/index.php)
-   Beyin Fırtınası (http://www.excel.web.tr/forumdisplay.php?f=142)
-   -   Seçime uyan verilerin sayısına ulaşmak (http://www.excel.web.tr/showthread.php?t=149097)

Korhan Ayhan 24-05-2015 23:50

Seçime uyan verilerin sayısına ulaşmak
 
1 Eklenti(ler)
İyi Akşamlar Değerli Forum Üyeleri,

Bu bölüme uzun süredir soru sormuyordum. Bir çalışma ile uğraşırken bu bölüme uygun olabileceğini düşündüm.

Konuyla ilgili alternatif cevapların iyi bir beyin fırtınası olacağını düşünüyorum.

Gelelim soruma;

Excel sayfalarında birkaç sütundan oluşan benzer tablolarım var.
Ana sayfamda belirlediğim sütunlardaki verilerden istediklerimi seçerek, seçime uyan kayıtların sayısını öğrenmek istiyorum. Seçim yaparken bir kısıtlama yoktur. 3 kriteri seçebileceğim gibi tek kriterde seçebilirim. Uygulanacak çözümün her şekilde sonuç vermesi gerekiyor.

Örnek dosya ektedir.

1Al2Ver 25-05-2015 00:34

1 Eklenti(ler)
Merhaba,

Size uygun bir çözüm mü bilemedim ama basit bir yöntemle oldu sanırım.

turist 25-05-2015 00:53

1 Eklenti(ler)
Alternatif dosya eklidir.

Ömer BARAN 25-05-2015 01:06

Merhabalar Sayın AYHAN.

Ben olsam (makro olayına hakim olmadığımdan formül ile çözüm bulmak için;
BLOK sayfalarının F3 hücrelerine aşağıdaki formülü uygular ve aşağı doğru listeler boyunca kopyalardım.
Kod:

=EĞER(EĞER(ÖZET!$B$2<>"";D3;"")&EĞER(ÖZET!$B$3<>"";C3;"")&EĞER(ÖZET!$B$4<>"";E3;"")=EĞER(ÖZET!$B$2<>"";ÖZET!$B$2;"")&EĞER(ÖZET!$B$3<>"";ÖZET!$B$3;"")&EĞER(ÖZET!$B$4<>"";ÖZET!$B$4;"");MAK($F$2:F2)+1;"")
Sonra da ÖZET sayfasında da E2 hücresine;
Kod:

=MAK(DOLAYLI(E$1&"!$F$3:$F$9"))
formülünü uygulayıp sağa doğru çoğaltırdım.
Yanlış anlamadıysam bu şekilde sonuç alınabiliyor.

Korhan Ayhan 25-05-2015 01:11

Değerli Arkadaşlar,

Amacımız yardımcı alan kullanmadan direkt mümkün olduğunca kısa bir formülle çözüme ulaşmaktır.

İdris SERDAR 25-05-2015 09:12

1 Eklenti(ler)
.

E2 hücresine:

Kod:

=IFERROR(SUMPRODUCT(COUNTIFS(INDIRECT("'"&E1&"'!D2:D20");$B$2;INDIRECT("'"&E1&"'!C2:C20");$B$3;INDIRECT("'"&E1&"'!E2:E20");$B$4));"")
yazıp. sağa doğru kopyalayın.

Dosya ekte.

Ayrıca, buradaki SUMIFS ile yapılan örnekler, bir fikir verebilir. COUNTIFS'e uyarlayabilirsiniz.

http://www.excelgurusu.com/3d-3b-sumifs-coketopla/


http://www.excelgurusu.com/3d-3b-sum...ifs-coketopla/


.

kuvari 25-05-2015 09:24

Korhan bey merhaba,

E2 hücresine,dizi formülüdür.

Kod:

=TOPLA.ÇARPIM(--(EĞER($B$4="";SATIR($1:$7)^0;DOLAYLI("'"&E1&"'!E3:E9")=$B$4))*(EĞER($B$3="";SATIR($1:$7)^0;DOLAYLI("'"&E1&"'!c3:c9")=$B$3))*(EĞER($B$2="";SATIR($1:$7)^0;DOLAYLI("'"&E1&"'!d3:d9")=$B$2)))

Ömer 25-05-2015 18:39

Merhaba,

Veri düzenine bakınca aranan ölçütlerin satır sırasıyla, sayfadaki aradığımız verilerin sütun sıraları farklı. Yalnız veri içerikleri birbiriyle tamamen farklı olduğu için sıranın önemini gözardı ederek hesaplama yapabiliriz. Sonucu değiştirmeyecektir.

Dizi formülü:

Kod:

=TOPLA(--(DÇARP(EĞERSAY($B$2:$B$4;DOLAYLI("'"&E1&"'!C3:E9"))
 ;SATIR($B$2:$B$4)^0)=BAĞ_DEĞ_DOLU_SAY($B$2:$B$4)))

------------------------------------------------------------------------------

Eğer veri içerikleri benzerlik taşırsa yada sütunları birbirinden kopuksa, arama ölçütü ile aranan değerin sırasını düzenlemek formülü daha kullanışlı yapar. Değiştirme durumu yoksa aşağıdaki gibi basit mantıkla formülü yazabilirsiniz.

Aşağıdaki formülü tek sayfa varmış gibi yazdım, dolaylı eklemesini yapmadım.

Kod:

=TOPLA.ÇARPIM(--(('1.BLOK'!D3:D9=B2)+('1.BLOK'!C3:C9=B3)+('1.BLOK'!E3:E9=B4)
 =BAĞ_DEĞ_DOLU_SAY(B2:B4)))

.

Korhan Ayhan 25-05-2015 23:35

Merhaba Değerli Arkadaşlar,

İdris bey sizin önerinizde otel adını silince formül sıfır değerini veriyor.

Sayın Kuvari sizin önerinizde olumlu sonuç alabiliyorum.

Ömer Bey sizin önerinizde olumlu sonuç veriyor ve oldukça kısa bir formül oldu.

Korhan Ayhan 27-05-2015 00:06

Sayın Kuvari sizin önerinizde olumlu sonuç alabiliyorum. Fakat kriterlerden birisini silince formül hata veriyor.


Saat 13:52

Powered by vBulletin Version 3.7.2
Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.