Excel Forum
ALTIN ÜYELİK Hakkında Bilgi


Geri Git   Excel Forum > EXCEL-Soruları > Makro-VBA
Atatürk
Şifremi Unuttum

DUYURU SİSTEMİ / REKLAM PANOSU

Makro-VBA Makro veya VBA ile ilgili sorularınızı buraya gönderebilirsiniz.
Dosya ekleyebilirsiniz

Özel Arama


Yanıtla
 
Paylaş Konu Araçları Görünüm Modları
Eski 17-07-2017, 15:53   #1
BedriA
Altın Üye
 
Giriş: 03/06/2017
Şehir: Antalya
Mesaj: 450
Excel Vers. ve Dili:
2007, 32
Varsayılan Abby Finereader Programına Makro İle İşlem Yaptırma

Arkadaşlar,

Ekteki resimde görüldüğü gibi eğer bilgisayarda Abby Finereader programı yüklü ise Office dosyalarında bu program eklenti olarak görünüyor.

Bu eklentiyi kullanarak PDF dosyasını excele dönüştürüyorum.
Bu dönüştürme işlemini kod ile yaptırmak mümkün mü acaba?
Eklenmiş Resimler
Dosya Türü: jpg Adsız.jpg (19.4 KB, 9 Görüntülenme)
__________________
Mutluluğun kodunu yazabilir misin Abidin?
BedriA Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 16:20   #2
asri
Altın Üye
 
Giriş: 24/04/2005
Şehir: Istanbul
Mesaj: 1,912
Excel Vers. ve Dili:
Office 2010 Tr
Varsayılan

PDF den Excel e dönüştürmek için madem ücretli bir program kullanılacak.
Adobe acrobat ı öneririm. Adobe Reader değil.

İnternette bulduğum iyi bir örnek ektedir.

Deneme sürümü için.
https://acrobat.adobe.com/tr/tr/free...-download.html

Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Option Explicit
Option Private Module

Sub ExportAllPDFs()
    
    '----------------------------------------------------------------
    'Converts all the PDF files that their paths are in column A of
    'the worksheet "Convert PDF Files" into a different file format,
    'based on the value in column B (extension).
    
    'By Christos Samaras
    'Date: 18/07/2013
    'http://www.myengineeringworld.net
    '----------------------------------------------------------------

    Dim LastRow As Long
    Dim i As Integer
    
    shPaths.Activate
    
    'Find the last row.
    With shPaths
        LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
    End With
    
    'Check that there are available file paths.
    If LastRow < 2 Then
        shPaths.Range("A2").Select
        MsgBox "There are no file paths to convert!", vbInformation, "File paths missing"
        Exit Sub
    End If
        
    'Checking for errors before conversion.
    For i = 2 To LastRow
    
        'Check if the file extensions are not empty.
        If Cells(i, 2).Value = "" Then
            shPaths.Cells(i, 2).Select
            MsgBox "Please select an output format from the dropdown list!", vbCritical, "File paths missing"
            Exit Sub
        End If
        
        'Check if the file exists.
        If Dir(shPaths.Cells(i, 1).Value) = "" Then
            shPaths.Cells(i, 1).Select
            MsgBox "The file path is not valid!", vbCritical, "File path error"
            Exit Sub
        End If
    
        'Check if the input file is a PDF file.
        If LCase(Right(shPaths.Cells(i, 1).Value, 3)) <> "pdf" Then
            shPaths.Cells(i, 1).Select
            MsgBox "The file is not a pdf file!", vbCritical, "No pdf file"
            Exit Sub
        End If
        
    Next i
    
    'For each cell in the range "A2:A" & last row convert the pdf file
    'into different format according to the "B2:B" & last row value.
    For i = 2 To LastRow
        SavePDFAs Cells(i, 1).Value, Cells(i, 2).Value
    Next i
    
    'Adjust the two columns.
    Columns("A:B").EntireColumn.AutoFit
     
    'Inform the user that conversion finished.
    MsgBox "All files were converted successfully!", vbInformation, "Finished"
    
End Sub

Private Sub SavePDFAs(PDFPath As String, FileExtension As String)
    
    '---------------------------------------------------------------------------------------
    'Saves a PDF file as other format using Adobe Professional.
    
    'In order to use the macro you must enable the Acrobat library from VBA editor:
    'Go to Tools -> References -> Adobe Acrobat xx.0 Type Library, where xx depends
    'on your Acrobat Professional version (i.e. 9.0 or 10.0) you have installed to your PC.
    
    'Alternatively you can find it Tools -> References -> Browse and check for the path
    'C:\Program Files\Adobe\Acrobat xx.0\Acrobat\acrobat.tlb
    'where xx is your Acrobat version (i.e. 9.0 or 10.0 etc.).
    
    'By Christos Samaras
    'Date: 30/03/2013
    'http://www.myengineeringworld.net
    '---------------------------------------------------------------------------------------
    
    Dim objAcroApp      As Acrobat.AcroApp
    Dim objAcroAVDoc    As Acrobat.AcroAVDoc
    Dim objAcroPDDoc    As Acrobat.AcroPDDoc
    Dim objJSO          As Object
    Dim boResult        As Boolean
    Dim ExportFormat    As String
    Dim NewFilePath     As String
        
    'Initialize Acrobat by creating App object.
    Set objAcroApp = CreateObject("AcroExch.App")
    
    'Set AVDoc object.
    Set objAcroAVDoc = CreateObject("AcroExch.AVDoc")
    
    'Open the PDF file.
    boResult = objAcroAVDoc.Open(PDFPath, "")
        
    'Set the PDDoc object.
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc
    
    'Set the JS Object - Java Script Object.
    Set objJSO = objAcroPDDoc.GetJSObject
    
    'Check the type of conversion.
    Select Case LCase(FileExtension)
        Case "eps": ExportFormat = "com.adobe.acrobat.eps"
        Case "html", "htm": ExportFormat = "com.adobe.acrobat.html"
        Case "jpeg", "jpg", "jpe": ExportFormat = "com.adobe.acrobat.jpeg"
        Case "jpf", "jpx", "jp2", "j2k", "j2c", "jpc": ExportFormat = "com.adobe.acrobat.jp2k"
        Case "docx": ExportFormat = "com.adobe.acrobat.docx"
        Case "doc": ExportFormat = "com.adobe.acrobat.doc"
        Case "png": ExportFormat = "com.adobe.acrobat.png"
        Case "ps": ExportFormat = "com.adobe.acrobat.ps"
        Case "rft": ExportFormat = "com.adobe.acrobat.rft"
        Case "xlsx": ExportFormat = "com.adobe.acrobat.xlsx"
        Case "xls": ExportFormat = "com.adobe.acrobat.spreadsheet"
        Case "txt": ExportFormat = "com.adobe.acrobat.accesstext"
        Case "tiff", "tif": ExportFormat = "com.adobe.acrobat.tiff"
        Case "xml": ExportFormat = "com.adobe.acrobat.xml-1-00"
        Case Else: ExportFormat = "Wrong Input"
    End Select
    
    'Check if the format is correct and there are no errors.
    If ExportFormat <> "Wrong Input" And Err.Number = 0 Then
        
        'Format is correct and no errors.
        
        'Set the path of the new file. Note that Adobe instead of xls uses xml files.
        'That's why here the xls extension changes to xml.
        If LCase(FileExtension) <> "xls" Then
            NewFilePath = WorksheetFunction.Substitute(PDFPath, ".pdf", "." & LCase(FileExtension))
        Else
            NewFilePath = WorksheetFunction.Substitute(PDFPath, ".pdf", ".xml")
        End If
        
        'Save PDF file to the new format.
        boResult = objJSO.SaveAs(NewFilePath, ExportFormat)
        
        'Close the PDF file without saving the changes.
        boResult = objAcroAVDoc.Close(True)
        
        'Close the Acrobat application.
        boResult = objAcroApp.Exit
        
    Else
        
        'Something went wrong, so close the PDF file and the application.
        
        'Close the PDF file without saving the changes.
        boResult = objAcroAVDoc.Close(True)
        
        'Close the Acrobat application.
        boResult = objAcroApp.Exit

    End If
        
    'Release the objects.
    Set objAcroPDDoc = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroApp = Nothing
        
End Sub
Eklenmiş Dosyalar
Dosya Türü: xlsm Convert PDF Files Into Different Format.xlsm (31.9 KB, 7 Görüntülenme)
__________________
www.asriakdeniz.com
asri Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 16:30   #3
BedriA
Altın Üye
 
Giriş: 03/06/2017
Şehir: Antalya
Mesaj: 450
Excel Vers. ve Dili:
2007, 32
Varsayılan

Asri Hocam,

Abby Finerader için uyarlama yapmak mümkün mü acaba?
Diğer programı almak mümkün değil şu an.
__________________
Mutluluğun kodunu yazabilir misin Abidin?
BedriA Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 19:01   #4
BedriA
Altın Üye
 
Giriş: 03/06/2017
Şehir: Antalya
Mesaj: 450
Excel Vers. ve Dili:
2007, 32
Varsayılan

Asri Hocam,

Adobe Acrobat'ı kurdum.
Örnek dosyayı indirdim ama sürekli uyarı mesajı alıyorum ve işlem yapamıyorum.
Dönüştürülecek PDF dosyası nerde olmalı?
__________________
Mutluluğun kodunu yazabilir misin Abidin?
BedriA Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 19:03   #5
asri
Altın Üye
 
Giriş: 24/04/2005
Şehir: Istanbul
Mesaj: 1,912
Excel Vers. ve Dili:
Office 2010 Tr
Varsayılan

Alıntı:
BedriA tarafından gönderildi Mesajı Görüntüle
Asri Hocam,

Adobe Acrobat'ı kurdum.
Örnek dosyayı indirdim ama sürekli uyarı mesajı alıyorum ve işlem yapamıyorum.
Dönüştürülecek PDF dosyası nerde olmalı?
Excel dosyasında tam yolu belirtmeniz gerekiyor.
C:\deneme\pdfler\excelyapilacakpdf.pdf gibi. hemen sonraki kolonda xlsx i seçin

Şimdi dosyayı denedim. Sorunsuz excel e çevirdi.
__________________
www.asriakdeniz.com
asri Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 19:25   #6
BedriA
Altın Üye
 
Giriş: 03/06/2017
Şehir: Antalya
Mesaj: 450
Excel Vers. ve Dili:
2007, 32
Varsayılan

Alıntı:
asri tarafından gönderildi Mesajı Görüntüle
Excel dosyasında tam yolu belirtmeniz gerekiyor.
C:\deneme\pdfler\excelyapilacakpdf.pdf gibi. hemen sonraki kolonda xlsx i seçin

Şimdi dosyayı denedim. Sorunsuz excel e çevirdi.

Asri Hocam,

Ekteki PDF belgesini bu yöntemle Excele çevirmeyi deneyebilir misiniz?
Eklenmiş Dosyalar
Dosya Türü: pdf 0001 - 0001.pdf (16.6 KB, 7 Görüntülenme)
__________________
Mutluluğun kodunu yazabilir misin Abidin?
BedriA Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 19:27   #7
asri
Altın Üye
 
Giriş: 24/04/2005
Şehir: Istanbul
Mesaj: 1,912
Excel Vers. ve Dili:
Office 2010 Tr
Varsayılan

Alıntı:
BedriA tarafından gönderildi Mesajı Görüntüle
Asri Hocam,

Ekteki PDF belgesini bu yöntemle Excele çevirmeyi deneyebilir misiniz?
Ek yoktu
__________________
www.asriakdeniz.com
asri Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 19:51   #8
asri
Altın Üye
 
Giriş: 24/04/2005
Şehir: Istanbul
Mesaj: 1,912
Excel Vers. ve Dili:
Office 2010 Tr
Varsayılan

Alıntı:
BedriA tarafından gönderildi Mesajı Görüntüle
Asri Hocam,

Ekteki PDF belgesini bu yöntemle Excele çevirmeyi deneyebilir misiniz?
Adobe Acrobat bu tür pdf leri çeviremez. Bu pdf de metinsel içerik yok sadece bir adet resimden oluşmuş
Excel e çevirdiğinde Excel in içinde bir adet resim olarak cevap anahtarı oluyor.

Resim den excel e çevirmeler için Abby ye devam edin.En iyisi bu.
__________________
www.asriakdeniz.com

Bu mesaj en son " 17-07-2017 " tarihinde saat 19:56 itibariyle asri tarafından düzenlenmiştir....
asri Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 20:18   #9
BedriA
Altın Üye
 
Giriş: 03/06/2017
Şehir: Antalya
Mesaj: 450
Excel Vers. ve Dili:
2007, 32
Varsayılan

Aslında paylaştığınız örnekteki gibi bir dosya yapılabilse, dediğiniz gibi bu iş için en iyisi Abby.

Halihazırda cevap anahtarlarını Aby ile dönüştürüp programa aktarıyorum ve programla kağıdı analiz edebiliyorum. Yani kullanıcının bu programla kağıt okuması için harici olarak Abby i kullanması gerekiyor.

Harici yapılan bu işi programın içinden Abby e yaptırmanın bir yolu yok mu? Paylaştığınız dosyada yapılan gibi?
__________________
Mutluluğun kodunu yazabilir misin Abidin?
BedriA Çevrimdışı   Alıntı Yaparak Cevapla
Eski 17-07-2017, 20:28   #10
asri
Altın Üye
 
Giriş: 24/04/2005
Şehir: Istanbul
Mesaj: 1,912
Excel Vers. ve Dili:
Office 2010 Tr
Varsayılan

Alıntı:
BedriA tarafından gönderildi Mesajı Görüntüle
Aslında paylaştığınız örnekteki gibi bir dosya yapılabilse, dediğiniz gibi bu iş için en iyisi Abby.

Halihazırda cevap anahtarlarını Aby ile dönüştürüp programa aktarıyorum ve programla kağıdı analiz edebiliyorum. Yani kullanıcının bu programla kağıt okuması için harici olarak Abby i kullanması gerekiyor.

Harici yapılan bu işi programın içinden Abby e yaptırmanın bir yolu yok mu? Paylaştığınız dosyada yapılan gibi?
Abby bu tür bir çalışmayı desteklemiyormuş.

"ABBYY FineReader, sonucu komut dosyasından kaydetmek veya toplu işlemek için komut satırı arabirimi sağlamaz. FineReader, UI tabanlı kullanım için tasarlanmış ve kara kutu entegrasyonu için tasarlanmamış bir masaüstü uygulamasıdır. Bu görev için uydurma ABBYY paket Btw CLEI önceden derlenmiş örnek olduğu doğru gelişim için Tanıma Server veya Motor SDK'dır."

"ABBYY FineReader does not provide command line interface for saving the result from scripting or for batch processing. FineReader is a desktop application intended for UI-driven use and not intended for black-box integration. The fitting ABBYY package for that task is Recognition Server or Engine SDK for true development, which btw has CLEI precompiled sample."
__________________
www.asriakdeniz.com
asri Çevrimdışı   Alıntı Yaparak Cevapla
Yanıtla


Konu Araçları
Görünüm Modları

Gönderme Kuralları
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is Açık
SimgelerAçık
[IMG] kodu Açık
HTML kodu Kapalı


Saat 08:46


Bu forum Elit NET - www.elitnet.com.tr tarafından sunulmaktadır.

Excel Eğitimi - Mobil Uygulama - Çorlu - Çorlu Hurda - Torna - Çorlu Web Tasarım - Tarot Falı - Fenerbahçe Haberleri - Trakya Haberleri - investing - Hurda - Kozmetik Ürünler - Excel Eğitimi - Lingerie - Dyeing Machine - Çorlu Temizlik- Hazır Site- SEO- Çorlu Burun Estetiği- Karton Bardak- Çorlu Pimapenci- İstanbul Avukat- Çorlu Rehabilitasyon- Edirne Su Arıtma- Çorlu Perde Yıkama- Marmara Ereğlisi Hotel- Site Yönetimi- Led Aydınlatma- Pronet Tekirdağ- Çorlu Pronet- Pronet Edirne- Pronet Kırklareli- Pronet Çerkezköy- Pronet Çorlu- Pronet Lüleburgaz- Pronet Keşan-
Powered by vBulletin Version 3.7.2
Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.
Advertisement System V2.6 By   Branden