Excel Forum
ALTIN ÜYELİK Hakkında Bilgi


Geri Git   Excel Forum > EXCEL-Soruları > Excel'e Yeni Başlayanlar
Atatürk
Şifremi Unuttum

DUYURU SİSTEMİ / REKLAM PANOSU

Excel'e Yeni Başlayanlar Excel kullanmaya yeni başladıysanız sorularınızı buraya gönderebilirsiniz.
Dosya ekleyebilirsiniz

Özel Arama


Yanıtla
 
Paylaş Konu Araçları Görünüm Modları
Eski 14-05-2018, 20:36   #1
yyhy
Altın Üye
 
Giriş: 03/12/2005
Şehir: Konya
Mesaj: 453
Excel Vers. ve Dili:
Office 2013 Pro
Varsayılan Excel to txt

Excelde kayıt ettiğim dataları d sürücüsü içerisine txt dosyası olarak kayıt etme konusunda elimde yine Excel Web Tr den aldığım yardımcı dosya ve kodlarla bir çalışma sayfası oluşturdum. Dosyada yapmak istediğim txt dosyasına veriler aktarılıyor yalnız verilerin hizalı olmasını istiyorum. Acaba verileri hizalı yapmak için bu dosya veya başka bir önerisi olan var mı? Şimdiden teşekkür ederim.
Eklenmiş Dosyalar
Dosya Türü: rar Xls to Txt Dönüştür Macro İle.rar (16.2 KB, 20 Görüntülenme)
yyhy Çevrimdışı   Alıntı Yaparak Cevapla
Eski 14-05-2018, 21:01   #2
ÖmerBey
Destek Ekibi
 
ÖmerBey kullanıcısının avatarı
 
Giriş: 22/10/2012
Mesaj: 2,067
Excel Vers. ve Dili:
2007 Türkçe
Varsayılan

Merhaba,
FileFormat seçeneğini xlText yapıp deneyiniz. Aynı işlemi excel farklı kaydet menüsünden Metin (Sekmeyle ayrılmış) seçeneğiyle de yapabilirsiniz.
iyi çalışmalar...
__________________
Alıntı:
evi Nepal'de kalmış
Slovakyalı salyangozdur ruhum
ÖmerBey Çevrimdışı   Alıntı Yaparak Cevapla
Eski 14-05-2018, 21:07   #3
Zeki Gürsoy
Uzman
 
Zeki Gürsoy kullanıcısının avatarı
 
Giriş: 30/12/2005
Şehir: Sakarya-Hendek
Mesaj: 3,455
Excel Vers. ve Dili:
Office 2016 (64 bit) - Türkçe
Varsayılan

Bunu "SaveAs" metodu yerine dosyalama metodunu kullanarak yapabilirsiniz. Dosyalama metodunu kullanmadan önce de, kolonlar için sabit uzunluklar belirlenmelidir.

Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Sub Test()
    Dim i, c1, c2, c3, c4, c5, c6, c7
    
    Open ThisWorkbook.Path & "\Demo.txt" For Output As #1
    
    For i = 1 To [b1000].End(3).Row
    
        c1 = Format(Cells(i, "b"), "!" & String(5, "@")) & " "
        c2 = Format(Cells(i, "c"), "!" & String(20, "@")) & " "
        c3 = Format(Cells(i, "d"), "!" & String(20, "@")) & " "
        c4 = Format(Cells(i, "e"), "!" & String(5, "@")) & " "
        c5 = Format(Cells(i, "f"), "!" & String(6, "@")) & " "
        c6 = Format(Cells(i, "g"), "!" & String(6, "@")) & " "
        c7 = Format(Cells(i, "h"), "!" & String(6, "@")) & " "
        
        Print #1, c1; c2; c3; c4; c5; c6; c7
        
    Next
    
    Close #1
    
End Sub
.
__________________

gursoyzeki@gmail.com




Zeki Gürsoy Çevrimdışı   Alıntı Yaparak Cevapla
Eski 14-05-2018, 21:49   #4
yyhy
Altın Üye
 
Giriş: 03/12/2005
Şehir: Konya
Mesaj: 453
Excel Vers. ve Dili:
Office 2013 Pro
Varsayılan

Öncelikle arkadaşlara teşekkür ederim. Ömer beyin yazmış olduğunu tam anlayamadım. Biraz açıklık getirebilir misiniz? Zeki Gürsoy kodlar işlemi istediğim gibi yapıyor ama uzunluk belirtilmeden kodlarda değişiklik yapılabilir mi?
yyhy Çevrimdışı   Alıntı Yaparak Cevapla
Eski 14-05-2018, 21:52   #5
Zeki Gürsoy
Uzman
 
Zeki Gürsoy kullanıcısının avatarı
 
Giriş: 30/12/2005
Şehir: Sakarya-Hendek
Mesaj: 3,455
Excel Vers. ve Dili:
Office 2016 (64 bit) - Türkçe
Varsayılan

Öngörülen bir uzunluk belirlemek zorundasınız. Ömer Bey'in önerisi "TAB" ile boşlık verebilir ancak aynı hizada olmayacaktır.

.
__________________

gursoyzeki@gmail.com




Zeki Gürsoy Çevrimdışı   Alıntı Yaparak Cevapla
Eski 14-05-2018, 22:15   #6
ÖmerBey
Destek Ekibi
 
ÖmerBey kullanıcısının avatarı
 
Giriş: 22/10/2012
Mesaj: 2,067
Excel Vers. ve Dili:
2007 Türkçe
Varsayılan

Alıntı:
Zeki Gürsoy tarafından gönderildi Mesajı Görüntüle
Öngörülen bir uzunluk belirlemek zorundasınız. Ömer Bey'in önerisi "TAB" ile boşlık verebilir ancak aynı hizada olmayacaktır.
Zeki Bey haklı, ben de durumu sonradan farkettim. Tab ile çözüm arıyordum, aşağıdaki gibi bir sonuca ulaştım. Alternatif olsun...
Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Sub kod()
ts = InputBox("Dosya Adı Girişi", "Dosya Adı Giriş")
If ts = "" Then Exit Sub
Open "D:\" & ts & ".txt" For Output As #1
For a = 1 To Range("B65500").End(3).Row
    For b = 2 To 8
        If b = 3 Or b = 4 Then
            If Len(Cells(a, b).Text) < 8 Then
                yaz = yaz & Cells(a, b).Text & vbTab & vbTab & vbTab
            ElseIf Len(Cells(a, b).Text) < 16 Then
                yaz = yaz & Cells(a, b).Text & vbTab & vbTab
            Else
                yaz = yaz & Cells(a, b).Text & vbTab
            End If
        Else
            yaz = yaz & Cells(a, b).Text & vbTab
        End If
    Next
    Print #1, yaz
    yaz = Empty
Next
Close #1
End Sub
__________________
Alıntı:
evi Nepal'de kalmış
Slovakyalı salyangozdur ruhum
ÖmerBey Çevrimdışı   Alıntı Yaparak Cevapla
Eski 14-05-2018, 22:55   #7
halit3
Uzman
 
halit3 kullanıcısının avatarı
 
Giriş: 18/01/2008
Mesaj: 10,763
Excel Vers. ve Dili:
2003 excel türkçe
Varsayılan

Alternatif olması açısından
farklı bir uygulama

Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Sub deneme()
Dim i, j, ara, yaz
Open ThisWorkbook.Path & "\Dem.txt" For Output As #1

ara = "                                                                   "

For i = 1 To Cells(Rows.Count, "B").End(3).Row
yaz = ""
For j = 2 To 8
yaz = yaz & Left(Cells(i, j) & ara, 20)
Next j
Print #1, yaz
Next
Close #1

End Sub


Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Sub deneme()
Dim i, j, yaz
Dim ara(8) As String * 20
Open ThisWorkbook.Path & "\Dem.txt" For Output As #1
For i = 1 To Cells(Rows.Count, "B").End(3).Row
yaz = ""
For j = 2 To 8
ara(j) = Cells(i, j)
yaz = yaz & ara(j)
Next j
Print #1, yaz
Next
Close #1
End Sub
__________________





Forum Kuralları
Ofis 2003 için makro güvenlik ayarları
http://www.excel.web.tr/f157/ofis-20...k-t104854.html
Ofis 2007 için makro güvenlik ayarları
http://www.excel.web.tr/f157/ofis-20...k-t104852.html
Timer Nesnesinin kurulumu
http://www.excel.web.tr/f167/timer-n...mu-t78713.html
halit3 Çevrimdışı   Alıntı Yaparak Cevapla
Eski 15-05-2018, 00:05   #8
Korhan Ayhan
Moderatör
 
Korhan Ayhan kullanıcısının avatarı
 
Giriş: 15/03/2005
Şehir: ANTALYA
Mesaj: 23,237
Excel Vers. ve Dili:
OFFICE 2013-2016 PRO TR
Varsayılan

Bir alternatifte ben sunayım.

Kod sütunlardaki maksimum uzunluğa göre "txt" dosyası oluşturuyor.

Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Option Explicit

Sub Txt_Dosyasi_Olustur()
    Dim Dosya_Sistemi As Object, Txt_Dosyasi, Dosya_Adi As String
    Dim Son As Long, X As Long, Y As Byte, Veri As String
    Dim Alan As String, Maksimum As Long
    
    Dosya_Adi = InputBox("Dosya adı giriniz...", "Dosya Adı Girişi")
    If Dosya_Adi = "" Then Exit Sub
    
    Set Dosya_Sistemi = CreateObject("Scripting.FileSystemObject")
    Set Txt_Dosyasi = Dosya_Sistemi.CreateTextFile("C:\Users\KORHAN\Desktop\" & Dosya_Adi & ".txt", True)
    
    Son = Cells(Rows.Count, 2).End(3).Row
    
    For X = 1 To Son
        For Y = 2 To 8
            Alan = Range(Cells(1, Y), Cells(Son, Y)).Address
            Maksimum = Evaluate("=MAX(LEN(" & Alan & "))")
            
            If Veri = "" Then
                Veri = Cells(X, Y) & WorksheetFunction.Rept(" ", Maksimum - Len(Cells(X, Y))) & vbTab
            Else
                Veri = Veri & Cells(X, Y) & WorksheetFunction.Rept(" ", Maksimum - Len(Cells(X, Y))) & IIf(Y = 8, "", vbTab)
            End If
        Next
        
        Txt_Dosyasi.WriteLine Trim(Veri)
        Veri = Empty
    Next
        
    Txt_Dosyasi.Close
    
    MsgBox "TXT dosyası oluşturulmuştur.", vbInformation
End Sub
__________________
.
.
.

Soru sormadan önce forumumuzun aşağıdaki
bölümlerini incelediğinizde birçok sorunuza yanıt bulabilirsiniz.


Excel Dersanesi
Uygulamalı Excel Eğitimi
Excel İçin Örnek Uygulamalar
Video Dersane (***Altın Üyelere Özel***)

Lütfen sorularınızın çözümlendiğine dair geri dönüş mesajı yazınız...!
Lütfen yazım ve forum kurallarına uyalım...!
Lütfen sorularımızı açık ve net bir dille ifade edelim...!



FORUM KURALLARI
Korhan Ayhan Çevrimdışı   Alıntı Yaparak Cevapla
Eski 15-05-2018, 02:14   #9
Tevfik_Kursun
Altın Üye
 
Giriş: 29/07/2012
Şehir: Antakya
Mesaj: 1,266
Excel Vers. ve Dili:
2010 - Türkçe 64 Bit
Varsayılan

Muhterem Arkadaşlar,
Alternatifler için ben de teşekkür ederim.
Saygılarımla
Tevfik_Kursun Çevrimdışı   Alıntı Yaparak Cevapla
Eski 15-05-2018, 14:08   #10
Haluk
Özel Üye
 
Giriş: 07/07/2004
Şehir: Türkiye
Mesaj: 5,661
Excel Vers. ve Dili:
Office 2010 - İngilizce
Varsayılan

Bir alternatif de ben vermiş olayım....

Gerçi, pek alternatif sayılmaz..... yukarıda Zeki Beyin önerdiği koddan çok farklı değil.

Sadece, hücrelerdeki verileri aktardığımız değişkenlerin Text dosyasında kaplayacakları alanları, kodun başında tarif ediyoruz.

Kod: (Rahat kopyalayabilmeniz için tüm kodu seçmenizi sağlar)
Sub Test2()
    Dim Sira As String * 5
    Dim Ad As String * 20
    Dim Soyad As String * 20
    Dim No As String * 5
    Dim Bilgi1 As String * 20
    Dim Bilgi2 As String * 20
    Dim Bilgi3 As String * 20

    Open ThisWorkbook.Path & "\Demo2.txt" For Output As #1
    
    For i = 1 To Range("B" & Rows.Count).End(3).Row
        Sira = Range("B" & i)
        Ad = Range("C" & i)
        Soyad = Range("D" & i)
        No = Range("E" & i)
        Bilgi1 = Range("F" & i)
        Bilgi2 = Range("G" & i)
        Bilgi3 = Range("H" & i)

        Print #1, Sira; Ad; Soyad; No; Bilgi1; Bilgi2; Bilgi3
    Next
    
    Close #1
End Sub
__________________
Kod anlatılmaz,yazılır !

(Özel sorularınız için sa4truss@gmail.com)
Haluk Çevrimdışı   Alıntı Yaparak Cevapla
Yanıtla


Konu Araçları
Görünüm Modları

Gönderme Kuralları
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is Açık
SimgelerAçık
[IMG] kodu Açık
HTML kodu Kapalı


Saat 13:56


Bu forum Elit NET - www.elitnet.com.tr tarafından sunulmaktadır.

Excel Eğitimi - Mobil Uygulama - Çorlu - Çorlu Web Tasarım -- Beylikdüzü mali müşavir - Beylikdüzü mali müşavir - Lingerie - Dyeing Machine - Karton Bardak- Karton Bardak- Çorlu Dil Konuşma Terapisti- Çorlu Dil Konuşma Terapisti- Çorlu Konuşma Terapisti- Çorlu Konuşma Terapisti- Çorlu Özel Eğitim- Site Yönetimi- Pronet Tekirdağ- Çorlu Kamera- Pronet Edirne- Pronet Çorlu- Çorlu Araç Takip- Rampa- Çorlu İnternet Sitesi- Çorlu Sürücü Kursu- Şişli Avukat- Çorlu Etüt- İstanbul Botanik- Çorlu Sigorta- Kağıt Bardak- Kağıt Bardak- Çorlu Havuz- Çorlu Havuz- Çorlu Perde Yıkama- Okul Danışmanlık- ADR'li taşıma kabı imalatı- Mekanik Tesisat- Çorlu Grafik Tasarım- Çorlu Sondaj- Çorlu Etüt- Futbol Cafe- Beylikdüzü Temizlik- Çorlu Kurs- Çorlu Ders- İzmit Mimar- Hurda Bakır Kablo- Hurda Bakır Kablo- Çorlu Pronet- Çorlu Yönetim- Çorlu Apartman Yönetimi- Çorlu Marangoz- Çorlu Avukat- Çorlu Su Arıtma- Çorlu Kompresör- İstanbul İnşaat-
Powered by vBulletin Version 3.7.2
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
Advertisement System V2.6 By   Branden