Excel Küp denkleminin Çözümü

[ilker611]

merhabalar benim sorunum excelde küp denklemelrinin parametrelerinin tahmin edilmesi aslında iki değişken arasında grafik oluşturup eğilim çizgisi ekle ile denklemleri tahmin edebiliriz ancak benim sorum bu denklemin parametrelerini excel macro kodları ile tahmin etmek
yardımlarınız için şimdiden tşk....

[Ferhat Pazarçevirdi]

Ekteki örneği inceleyiniz.

Veri setindeki 100 çiftlik veri için; Excel'in grafik motoru kullanılarak elde edilen 3.Derece trend denkleminin katsayıları, aşağıdaki kodlar vasıtasıyla elde edilmektedir.

Sub Grafik_Denklemi()
Dim cht As Chart
Dim wks As Worksheet
Dim oTrd As Trendline
Dim oLbl As DataLabel
Dim vElm As Variant
Dim i As Integer

Set wks = Sheets("Sayfa1")
wks.ChartObjects.Delete

Set cht = Charts.Add
Set cht = cht.Location(xlLocationAsObject, wks.Name)

With cht
With .Parent
.Top = Range("A4").Top
.Left = Range("E1").Left
.Width = Range("E4:M4").Width
.Height = Range("E4:E25").Height
End With

.ChartType = xlXYScatterLinesNoMarkers
.SetSourceData wks.Range("B4:C104"), xlColumns
.Legend.Delete
.Axes(xlValue).MajorGridlines.Delete
.PlotArea.ClearFormats

Set oTrd = .SeriesCollection(1).Trendlines.Add(Type:=xlPolyno mial, _
Order:=3, _
Forward:=0, _
Backward:=0, _
DisplayEquation:=True, _
DisplayRSquared:=False)

Set oLbl = oTrd.DataLabel
With oLbl
.Border.LineStyle = xlNone
.Interior.ColorIndex = 2
With .Font
.ColorIndex = 3
.Bold = True
End With
End With


End With

With wks

.Range("G29") = oLbl.Text

For Each vElm In Split(Replace(oLbl.Text, "y = ", ""), "x")
i = i + 1
Select Case i
Case 1, 4
If Len(CStr(vElm)) > 0 Then
.Range("G" & i + 30) = CDbl(vElm)
Else
.Range("G" & i + 30) = 0
End If
Case 2, 3
If Len(CStr(vElm)) > 0 Then
.Range("G" & i + 30) = CDbl(Mid(CStr(vElm), 2, Len(CStr(vElm))))
Else
.Range("G" & i + 30) = 0
End If
End Select
Next

.Range("A1").Select

End With


Set cht = Nothing
Set wks = Nothing
Set oTrd = Nothing
Set oLbl = Nothing
End Sub

[ilker611]

Merhaba Ferhat bey,
Gercekten en içten dilleklerimle tşk ederim.....

[ismailyardimci]

Ferhat bey,

Ciddi manada teşşekürü bir borç bilirim size, inanılmaz işime yarayan bir kod oldu ayriyetten, bu siteyi kuran ve yöneten arkadaşlardan allah razı olsun, herkese selam ve saygılar.

[ertugrullaydin]

merhaba ferhat bey yaptığınız programı çalıştıramadım, neden bilmiyorum ama böyle birşeye ihtiyacım var verilerle girilerek oluşturulan bir grafiğin eğiminin denkleminin katsayılarını buluyo galiba bende böle bişey arıyordum ama neden çalışatıramadım bilmiyorum. bana yardımcı olrusanız sevinirim verileri değiştiriyorum grafik ve eğimin denklemi değişiyor sonra "yeniden hesapla" ya tıklıyorum ama 3.2.1 , 3.2.2 , 3.2.3 falan (yani denkelmin katsayıları) değişmiyor. Şimdiden teşekkürler.